/* ++									      */
/* Nom                                                                        */
/*		INSTALL.CDCL                                                  */
/*                                                                            */
/* Description                                                                */
/*	Procédure d'aide à l'installation de l'éditeur de fontes pour LN03.   */
/*	Elle appelle INSTALL_UTIL.COM qui controle l'existance des noms	      */
/*	logiques UTL$...						      */
/*                                                                            */
/* Utilisation                                                                */
/* 	@INSTALL                                                              */
/*                                                                            */
/* Priviléges éventuels                                                       */
/*	Création de directories.                                              */
/*	Définition de noms logiques.                                          */
/*	Copie des fichiers dans les directories de receptions.                */
/*                                                                            */
/* Création                                                                   */
/*	22 Avril 1986 : JN Albert - LAL                                       */
/*                                                                            */
/* Modification                                                               */
/* --                                                                         */


/*	Installation de l'editeur					*/

	Type Sys$Input
#
#	L'editeur de fontes de caracteres pour LN03 est prevu pour etre 
# installer dans un sous-directory de UTL$SYSTEM.
#
#	Cette procedure verifie et eventuellement construit l'arborescence
# UTL$...
#	Elle copie ensuite les fichiers de l'editeur dans le directory.
#	Enfin, elle permet d'installer un ensemble de fichiers de fontes issus
# de TeX dans un directory UTL$SYSROOT:[TEX]. Cette derniere installation est
# optionnelle.
#

	inquire Fontes_TeX "Voulez-vous installer les fontes TeX (Y/N) "

/*	Verification et eventuellement creation des UTL$...		*/

	@INSTALL_UTIL

	if ($Status .ne. 1)
	   {
		Write SYS$OUTPUT "Installation impossible de EDIT_FONTES"
		Exit $status
	   }

	Set noon

/*	Creation d'un sous-directory  EDIT_FONTES 			*/

	Write sys$output ""
	Write sys$output "Debut de l'installation de EDIT_FONTES"
	Write sys$output ""

	utl_system = F$Logical("UTL$SYSTEM")
	dir_edit  = utl_system - "]" + ".EDIT_FONTES]"

	if (F$Search("UTL$SYSROOT:[SYSEXE]Edit_fontes.DIR") .eqs. "")
	   {
		Write sys$output \
		  "Creation d'un sous-directory [.EDIT_FONTES] dans UTL$SYSTEM"

		Create/Directory/Log 'dir_edit'
	   }

/*	Probleme de la library C					*/

	if (F$search("SYS$SHARE:VAXCRTL.EXE") .eqs. "")
	   {
		Write Sys$output "Installation sans librairie partagee"
		Copy [.editeur]edit_fonte_noshare.exe \
				'dir_edit'edit_fontes.exe
	   }
	else
	   {
		Write Sys$output "Installation avec librairie partagee"
		Copy [.editeur]edit_fontes_share.exe \
				'dir_edit'edit_fontes.exe
	   }

/*	Copies des autres fichiers					*/

	Write sys$output "Copie des fichiers"

	Copy [.editeur]Copy_fonte.com, Fontes.com, Fonte_Ln03.com 'dir_edit'
	Copy [.editeur]edit_fontes.gbl, edit_fontes.hlb 'dir_edit'
	Copy [.editeur]flip.exe, ffc.exe, ln03topp.exe 'dir_edit'
	Copy [.editeur]Edit_fontes.com 'utl_system'

	write sys$output "Fin de l'installation de l'editeur"

/*	Fontes de TeX							*/

	if (Fontes_TeX)
	   {
		write sys$output "Creation du directory UTL$SYSROOT:[TEX]"
		Create/directory UTL$SYSROOT:[TEX]

		write sys$output "Copies des fontes"
		Backup [.tex...] Utl$sysroot:[TEX...]

		Write sys$output "Fin de l'installation des fontes TeX"
	   }
	else
		write sys$output "Les fontes TeX ne sont pas copiees"

	Write Sys$output "Fin de l'installation de EDIT_FONTES"
